Intusoft Nonlinear Transient PWM IC Models
Date: 2/95
This model is part of the Power Supply Designers Library which
includes over 20 more PWM IC models, nonlinear magnetics cores,
power factor corrector models, and power mosfet drivers.
Copyright © Intusoft 1995
Tel (310) 833-0710
Fax (310) 833-9658
e-mail: info@intusoft.com
World Wide Web site: http://www.intusoft.com
SPICE Simulation Models
These SPICE simulation models may be used and distributed freely,
provided they are not altered in any way, resold, or included in
any other package for resale. In addition, the Intusoft copyright
notice MUST be maintained and included with any model distribution.
As a service to our customers, we provide a free modeling service.
If you are interested in obtaining additional models, please contact
Intusoft technical support.
ICAP/4 Windows Demonstration Software
The demonstration version of ICAP/4 Windows including IsSpice4 may be
downloaded from our Web site at no charge.
Also available for download are additional models, product and
ordering information, technical articles, and Intusoft Newsletters.
SpiceMod Modeling Software
SpiceMod is a CAE program that is used to create SPICE models from
data sheet values. SPICEMOD is particularly useful in the circuit
design phase because it allows the designer to create SPICE models
based on electrical specifications before an actual device is selected.
SpiceMod may be used to create models for diodes, Zener diodes, BJTs,
power BJTs, Darlington BJTs, JFETs, MOSFETs, power MOSFETs, IGBTs,
SCRs, and TRIACS.
*************
Macromodels, simulation models, or other models provided by
Intusoft, directly or indirectly, are not warranted by
Intusoft as fully representing all of the specifications and
operating characteristics of the semiconductor product to
which the model relates. Moreover, these models are
furnished on an "as is" basis without support or warranty of
any kind, either expressed or implied, regarding the use
thereof and Intusoft specifically disclaims all implied
warranties of merchantability and fitness of the models for
any purpose. Intusoft does not assume any liability arising
out of the application or use of the models including
infringement of patents and copyrights nor does Intusoft
convey any license under its patents and copyrights or the
rights of others. Intusoft reserves the right to make
changes without notice to any model.
Although the use of macromodels can be a useful tool in evaluating
device performance in various applications, they cannot
model exact device performance under all conditions, nor are
they intended to replace breadboarding for final
verification.
********
*SRC=UC1843;UC1843;PWM Models;Unitrode;Full Transient
*SYM=1845
.SUBCKT UC1843 3 14 15 1 18 4 20 2
* E/A FDBK IS RT/CT GND OUT VC VREF
****OSCILLATOR*****
S1 8 18 1 18 SOSC
.MODEL SOSC SW(RON=.01 ROFF=1MEG VT=1.9 VH=.85)
BDISCH 1 18 I=V(8,18) < 2.5 ? V(13,18) > 2.5 ? 10M : 0
RPULL 8 2 100K
****UVLO***********
S4 20 19 20 18 SUVLO
.MODEL SUVLO SW(RON=.01 ROFF=1MEG VT=8 VH=.4)
RUVLO 19 18 1MEG
RSTDBY 20 18 16.8K
ROP 10 18 500
****REFERENCE*******
BREF 13 18 V=V(19,18) > 6 ? 5 : 0
RREG 10 2 .33
CREF 2 18 1n
V3 13 10
B6 19 18 I=I(V3)
****CURRENT COMPARATOR*******
B3 21 18 V=V(15,18) > V(16,18) ? 5 : 0
R7 15 18 1MEG
RDELAY 21 22 1K
CDELAY 22 18 150P
****ERROR AMPLIFIER**********
XAMP 2 14 3 18 1845AMP
****OFFSET LIMITER***********
R4 12 11 2MEG
R6 11 18 1MEG
B2 16 18 V=V(11,18) > 1 ? 1 : V(11,18)
V4 3 9 1
D1 9 12 D2
.MODEL D2 D
****OUTPUT DRIVER************
XDRIVE 19 18 5 4 1845OUT
****S-R LATCH****************
XLATCH 8 2 22 18 6 7 FFLOP
****OUTPUT AND GATE**********
B8 5 18 V=V(2,18) > 2.5 ? V(7,18) > 2.5 ? V(8,18) > 2.5 ? 10 : 0
.ENDS
*include pwmic.lib
*********
*SYM=1845AMP
.SUBCKT 1845AMP 4 1 9 20
* VREF INV OUT V-
.MODEL QPMOD PNP
.MODEL DCLAMP D (RS=10 BV=5 IBV=.01)
.MODEL DMOD D
R1 10 4 100K
R2 10 20 100K
R3 6 20 316MEG
C1 6 20 15.9P
E1 5 20 6 20 1
R4 1 20 8MEG
I2 4 9 .8M
D12 9 4 DMOD
R6 20 3 300
D11 9 12 DMOD
Q1 20 13 12 QPMOD
I3 13 20 68U
D14 3 13 DMOD
D15 20 6 DCLAMP
L1 2 3 10U
C2 3 20 200P
R9 5 2 5
C5 2 20 .02U
G1 20 6 10 1 100U
.ENDS
*********
*SYM=OUT
.SUBCKT 1845OUT 4 7 3 12
* +V -V IN OUT
.MODEL QMOD NPN RC=1.5 RE=.5 RB=100 IKF=0.5
.MODEL QMOD2 NPN
.MODEL QIN NPN BF=100 BR=2 IS=1E-16 VAF=50
+ CJE=1.5P CJC=.15P TR=1N TF=4N
.MODEL DMOD D RS=1 IS=0.4U
I3 4 8 100U
D3 8 4 DMOD
D4 12 8 DMOD
Q3 8 1 9 QIN
Q4 12 9 7 QMOD
Q5 4 8 6 QMOD
I4 7 1 .9M
R1 3 2 10K
Q8 1 2 7 QIN
Q2 4 6 12 QMOD2
.ENDS
******************
*SYM=FFLOP
.SUBCKT FFLOP 1 2 11 12 5 6
* CLK D R S QBAR Q
.SUBCKT NAND3 1 2 3 4
B1 5 0 V=~(V(1)&V(2)&V(3))
R1 5 4 400
C1 4 0 20P IC={IC}
.ENDS
.SUBCKT INV 1 2
B1 3 0 V=~(V(1))
R1 3 2 100
C1 2 0 10P IC={IC}
.ENDS
X1 7 4 2 8 NAND3 {IC=0}
X2 8 3 10 9 NAND3 {IC=0}
X3 1 8 10 7 NAND3 {IC=3.5}
X4 4 9 1 10 NAND3 {IC=0}
X5 4 7 6 5 NAND3 {IC=3.5}
X6 5 10 3 6 NAND3 {IC=0}
X7 11 4 INV {IC=3.5}
X8 12 3 INV {IC=3.5}
.ENDS
********